The Spell Request Thread (Now with vJASS!)

[JIonaTaTa]

Well I'm at the moment when the map needs a good spells which are made professional

* A name for your spell - STFU
* The number of levels you spell should have - 1
* What the spell should do - Silence units (target type - Instant)
* The tooltip of the spell (else I will just make one up) - STFU !!!
* If you would like the spell in GUI or JASS - Both... I prefer to learn through this way
* If the spell needs to be MUI or not - Both versions?

[Zerzax]

Fulla, that makes sense. I'll use regular add-ability for the fade-in, timer for the fade-out.

[akolyt0r]

Originally Posted by JIonaTaTa

Well I'm at the moment when the map needs a good spells which are made professional

* A name for your spell - STFU
* The number of levels you spell should have - 1
* What the spell should do - Silence units (target type - Instant)
* The tooltip of the spell (else I will just make one up) - STFU !!!
* If you would like the spell in GUI or JASS - Both... I prefer to learn through this way
* If the spell needs to be MUI or not - Both versions?

well you can do that yourself, just base the ability of soulburn no scripting at all required.

[JIonaTaTa]

Originally Posted by akolyt0r

well you can do that yourself, just base the ability of soulburn no scripting at all required.

But this is targetable spell I'm searching for global spell that casts on all enemy units. Tried based on "channel" but I cannot find a way to make the trigger...

[Zerzax]

Here is Death Grip, non-MUI. It's still an awesome spell, and I intend to at some point make it MUI. I attempted doing this, and I think it was either beyond my scope or just my logic was screwed up, I got very close to fixing the bugs but it never happened and I've got so much going on at the moment. Since I promised a fast return, I'm putting this version up so xbadassx can see what it's like and use it in his map for the time being. The script isn't commented at all, so going to need to fix that at some point, as well as some optimizations.

Non-MUI script:

// Death Grip: Request by xbadassx in The Spell Request Thread at Wc3c.
// Coded by Zerzax
// Uses: TimerUtils and Parabolic Function.

scope DeathGrip initializer init

    globals
        private constant integer SPELL_ID='A000'
        private constant integer FLYING_HEIGHT_HACK='Amrf'
        
        private constant string LIGHTNING_PATH="DRAM"
        private constant string CHANNEL_ANIM="stand channel"
        private constant string GRAB_EFFECTS="Abilities\\Spells\\Human\\MarkOfChaos\\MarkOfChaosTarget.mdl"
        private constant string ATTACH_POINT="origin"
        private constant string END_ANIMATION="stand"
        
        private constant real BASE_LIGHTNING_HEIGHT=50.00
        private constant real MAXIMUM_DISTANCE=1200.00 // the spell cancels at this point
        private constant real MOVE_INTERVAL=0.02
        private constant real MOVE_OFFSET=25.00
        private constant real COLLISION_DISTANCE=16.00
        private constant real MAX_LIGHTNING_HEIGHT=100.00
        private constant real END_DISTANCE=70.00
    endglobals
    
    private function HookOffSet takes nothing returns real
        return 1 * MOVE_OFFSET
    endfunction
    
    private function DrawOffset takes nothing returns real
        return 1 * MOVE_OFFSET
    endfunction
    
    private struct grapple
        unit caster = null
        unit target = null
        timer moveTimer = null
        lightning hook
        
        integer phase=1
        
        real castX = 0 
        real castY = 0 
        real hookX = 0 
        real hookY = 0 
        real targX = 0 
        real targY = 0 
        real cos = 0
        real sin = 0
        
        real totalDist = 0.0
        real currentDist = 0.0
        integer count = 0
        
        boolean pastHijacking = false
        
        method warp takes nothing returns nothing
            set this.phase = 2 
            set this.totalDist = SquareRoot((this.castX - this.hookX)*(this.castX - this.hookX) + (this.castY - this.hookY)*(this.castY - this.hookY))
                
            call DestroyEffect(AddSpellEffectTargetById(SPELL_ID, EFFECT_TYPE_SPECIAL, this.target, ATTACH_POINT))
            call PauseUnit(this.target, true)
            call SetUnitInvulnerable(this.target, true)
            call UnitAddAbility(this.target, FLYING_HEIGHT_HACK)
            call UnitRemoveAbility(this.target, FLYING_HEIGHT_HACK)
            
            set this.cos=-this.cos
            set this.sin=-this.sin
            call SetUnitFacing(this.target, Atan2(this.castY - this.targY, this.castX - this.targX) * bj_RADTODEG )
        endmethod
        
        method pull takes nothing returns boolean
            local real currentZ=ParabolaZ(MAX_LIGHTNING_HEIGHT, this.totalDist, this.currentDist)
            
            set this.currentDist=this.currentDist + MOVE_OFFSET
            set this.targX = this.targX + MOVE_OFFSET * this.cos
            set this.targY = this.targY + MOVE_OFFSET * this.sin
            call SetUnitX(this.target, this.targX)
            call SetUnitY(this.target, this.targY)
            call SetUnitFlyHeight(this.target, currentZ, 0)
            call MoveLightningEx(this.hook, false, this.castX, this.castY, BASE_LIGHTNING_HEIGHT, this.targX, this.targY, currentZ) 
        
            return IsUnitInRangeXY(this.target, this.castX, this.castY, END_DISTANCE)
        endmethod
        
        method throw takes nothing returns boolean
            local real targX=GetUnitX(this.target)
            local real targY=GetUnitY(this.target)
            local real ang
                        
            if targX != this.targX or targY != this.targY then
                set this.targX = targX
                set this.targY = targY
                set ang=Atan2(targY - this.hookY, targX - this.hookX)
                set this.cos=Cos(ang)
                set this.sin=Sin(ang)
                call SetUnitFacing(this.caster, ang * bj_RADTODEG)
            endif
            
            set this.hookX=this.hookX + MOVE_OFFSET * this.cos
            set this.hookY=this.hookY + MOVE_OFFSET * this.sin
            call MoveLightning(this.hook, false, this.castX, this.castY, this.hookX, this.hookY) 
            
            return IsUnitInRangeXY(this.target, this.hookX, this.hookY, COLLISION_DISTANCE)
        endmethod
        
        static method update takes nothing returns nothing
            local grapple g=grapple(GetTimerData(GetExpiredTimer()))
            
            if IsUnitInRangeXY(g.target, g.castX, g.castY, MAXIMUM_DISTANCE) and GetWidgetLife(g.target) > 0.405 and GetWidgetLife(g.caster) > 0.405 then
                if g.phase == 1 and g.throw() then
                    call g.warp()
                elseif g.pull() then
                    call g.destroy()
                endif
            else
                call g.destroy()
            endif
        
        endmethod
    
        static method create takes unit c, unit t returns grapple
            local grapple g=grapple.allocate()
            local real castX=GetUnitX(c)
            local real castY=GetUnitY(c)
            local real ang
            
            set g.caster=c
            set g.target=t
            set g.castX=castX
            set g.castY=castY
            set g.hookX=castX
            set g.hookY=castY
            set g.targX=GetUnitX(t)
            set g.targY=GetUnitY(t) 

            set ang=Atan2(g.targY - castY, g.targX - castX)
            set g.cos=Cos(ang)
            set g.sin=Sin(ang)
            
            if g.hook == null then
                set g.hook=AddLightningEx(LIGHTNING_PATH, false, castX, castY, BASE_LIGHTNING_HEIGHT, castX, castY, BASE_LIGHTNING_HEIGHT)
            endif
            
            call PauseUnit(c, true)
            call SetUnitAnimation(c, CHANNEL_ANIM)
            
            set g.moveTimer=NewTimer()
            call SetTimerData(g.moveTimer, integer(g))
            call TimerStart(g.moveTimer, MOVE_INTERVAL, true, function grapple.update)
        
            return g
        endmethod
        
        method onDestroy takes nothing returns nothing
            call ReleaseTimer(this.moveTimer)
            call MoveLightning(this.hook, false, 0,0,0,0)
            
            call PauseUnit(this.caster, false)
            call SetUnitPosition(this.caster, this.castX, this.castY)
            call SetUnitAnimation(this.caster, END_ANIMATION)
            
            call SetUnitPosition(this.target, this.targX, this.targY)
            call SetUnitFlyHeight(this.target, 0, 0)
            call SetUnitInvulnerable(this.target, false)
            call PauseUnit(this.target, false)
        endmethod
    
    endstruct
    
    private function SpellExecute takes nothing returns nothing
        call grapple.create(GetTriggerUnit(), GetSpellTargetUnit())
    endfunction
    
    private function SpellCondition takes nothing returns boolean
        return GetSpellAbilityId()==SPELL_ID
    endfunction

    private function init takes nothing returns nothing
        local trigger t=CreateTrigger()
        call TriggerAddAction(t, function SpellExecute)
        call TriggerAddCondition(t, Condition(function SpellCondition))
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_SPELL_EFFECT)
    endfunction

endscope

So here you go for now.

[Zerzax]

Camouflage is donesky, I hope you enjoy it Fulla. I got lazy on the learn tooltip but I'm sure you can fix it up any way you like. Tell me if stuff isn't working, but it should be fine. At least it's commented, it was a short script.

Camouflage v1.0:

// Camouflage
// Coded by Zerzax as per Fulla's Request in Pyrogasm's Spell Request Thread
// Uses: Table

scope Camouflage initializer init

    // Configuration Section

    globals
        private constant integer ABILITY_ID = 'A002'
        private constant integer INVIS_ID = 'A001'
        private constant integer PRELOAD_ID = 'h000'
        // Timer Interval. Keep it large to minimize processing burdens.
        private constant real INTERVAL = 0.10
    endglobals

    // Range of trees.

    private function Range takes integer level returns real
        return 100.00 + level * 55.00
    endfunction
    
    // How many times the timer must run while the unit is out of range.
    
    private function FadeOut takes integer level returns integer
        return 7 + R2I( 3.3 * level )
    endfunction
    
    // Acceptable destructable types (that are trees)
    
    private function TreeTypes takes integer id returns boolean
        return id == 'ATtr' or id == 'BTtw' or id == 'KTtw' or id == 'YTft' or id == 'JTct' or id == 'YTst' or id == 'YTct' or id == 'YTwt' or id == 'JTwt' or id == 'JTwt' or id == 'FTtw' or id == 'CTtr' or id == 'ITtw' or id == 'NTtw' or id == 'OTtw' or id == 'ZTtw' or id == 'WTst' or id == 'LTlt' or id == 'GTsh' or id == 'Xtlt' or id == 'WTtw' or id == 'Attc' or id == 'BTtc' or id == 'CTtc' or id == 'ITtc' or id == 'NTtc' or id == 'ZTtc'
    endfunction
    
    // End of config. No Touchie!
    
    globals
        private group Camouflaged = null 
        private rect TreeFinder = null
        private HandleTable FadeCounter
        private boolexpr TreeFilter = null
        private boolean FoundTrees = false
    endglobals
    
    private function FindTree takes nothing returns boolean
        return TreeTypes(GetDestructableTypeId(GetFilterDestructable()))
    endfunction
    
    private function FoundTree takes nothing returns nothing
        set FoundTrees = true
    endfunction
    
    private function Enum takes nothing returns nothing
        local unit camouflaged = GetEnumUnit()
        local real cX = GetUnitX(camouflaged)
        local real cY = GetUnitY(camouflaged)
        local integer lvl = GetUnitAbilityLevel(camouflaged, ABILITY_ID)
        local real range = Range(lvl)
        
        call SetRect(TreeFinder, cX - range, cY - range, cX + range, cY + range) 
        call EnumDestructablesInRect(TreeFinder, TreeFilter, function FoundTree) // Enumerate.
        
        if FoundTrees then // Then the current unit is in range.
            set FoundTrees = false
            if GetUnitAbilityLevel(camouflaged, INVIS_ID) == 0 then
                call UnitAddAbility(camouflaged, INVIS_ID) // Add so he can fade in.
                call SetUnitAbilityLevel(camouflaged, INVIS_ID, lvl)
            else
                set FadeCounter[camouflaged] = 0 // Restart fade-out process
            endif
        elseif GetUnitAbilityLevel(camouflaged, INVIS_ID) > 0 then // Start the fade proccess.
            set FadeCounter[camouflaged] = FadeCounter[camouflaged] + 1
            if FadeCounter[camouflaged] >= FadeOut(lvl) then 
                call UnitRemoveAbility(camouflaged, INVIS_ID) // Fully faded.
                set FadeCounter[camouflaged] = 0
            endif
        endif
        
        set camouflaged = null
    endfunction
    
    private function GroupEnum takes nothing returns nothing
        call ForGroup(Camouflaged, function Enum) // Perform enum action on all learned units.
    endfunction
    
    private function LearnCondition takes nothing returns boolean
        return GetLearnedSkill() == ABILITY_ID and GetUnitTypeId(GetTriggerUnit()) != PRELOAD_ID
    endfunction
    
    private function OnLearn takes nothing returns nothing
        local unit learn = GetTriggerUnit() // The hero has learned the ability.
        if GetUnitAbilityLevel(learn, ABILITY_ID) == 1 then
            call GroupAddUnit(Camouflaged, learn)
            set FadeCounter[learn] = 0
        endif
        set learn = null
    endfunction

    private function init takes nothing returns nothing // Preload, trigger creation, handle creation.
        local unit preload = CreateUnit(Player(15), PRELOAD_ID, 0,0,0)
        local trigger t = CreateTrigger()
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_HERO_SKILL)
        call TriggerAddAction(t, function OnLearn)
        call TriggerAddCondition(t, Condition(function LearnCondition))
        
        set FadeCounter = HandleTable.create()
        set TreeFinder = Rect(0,0,0,0)
        set TreeFilter = Filter(function FindTree)
        set Camouflaged = CreateGroup()
        call TimerStart(CreateTimer(), INTERVAL, true, function GroupEnum)
            
        call UnitAddAbility(preload, ABILITY_ID)
        call UnitAddAbility(preload, INVIS_ID)
        call UnitRemoveAbility(preload, ABILITY_ID)
        call UnitRemoveAbility(preload, INVIS_ID)
        
        call RemoveUnit(preload)
        set preload = null
    endfunction

[Fulla]

Thx alot, much appreciated :)
Not sure if you're still taking requests especially with the spell contest starting, but I'll add one to the stack anyways, if that's ok.


Snare (Hero Ability 1)

Active Cast
Years of the hunt have honed the trolls skills to an incredible level. With just a few seconds preparation he is able to lay a snare which springs when a enemy Hero strays to close, trapping all nearby enemy units. The traps go invisible after 2 seconds & last a maximum of 120 seconds.

Level 1: Requires 3.0 seconds preparation, disables movement for 2.0 seconds.
Level 2: Requires 2.7 seconds preparation, disables movement for 2.3 seconds.
Level 3: Requires 2.3 seconds preparation, disables movement for 2.7 seconds.
Level 4: Requires 2.0 seconds preparation, disables movement for 3.0 seconds.

Note: Only activates when an enemy Hero walks over it, the disable is AoE, which should prefably only prevents movement. When it detonates it should destroy any nearby friendly snares as well, i.e. only 1 at a time in an area.

[Kyrbi0]

Originally Posted by Fulla

Level 1: Requires 3.0 seconds preparation, disables movement for 2.0 seconds.
Level 2: Requires 2.7 seconds preparation, disables movement for 2.3 seconds.
Level 3: Requires 2.3 seconds preparation, disables movement for 2.7 seconds.
Level 4: Requires 2.0 seconds preparation, disables movement for 3.0 seconds.

Hmm... Isn't that just "Casting Time"? Or because you want it to change with every level, you can't use that?

Also, someone's making a Troll hero. :P Interesting. Jungle Dartmon, much?

Also also, where can I get ahold of that "Camouflage" icon?

[Fulla]

Hmm... Isn't that just "Casting Time"? Or because you want it to change with every level, you can't use that?

Hmmm, good point! May as well throw in some AoE scaling as well per level.

Also, someone's making a Troll hero. :P Interesting. Jungle Dartmon, much?

Maybe :p - Jol'keat, the Jungle Warrior

Also also, where can I get ahold of that "Camouflage" icon?

I can't remember actually anymore, but simply
- 'right click'
- 'copy image'
- 'paste image' in an art program,
- Save as jpg or tga
- Convert to blp with war3viewer
- There you go..

[Kyrbi0]

Originally Posted by Fulla

Maybe :p - Jol'keat, the Jungle Warrior

Cool. Once again, the site project could've been an AoS, and we coulda done cool ideas like this.
But meh. I like mini-games, too.

Originally Posted by Fulla

I can't remember actually anymore, but simply
- 'right click'
- 'copy image'
- 'paste image' in an art program,
- Save as jpg or tga
- Convert to blp with war3viewer
- There you go..

D'oh. I've only got, like, Paint, but that should still work. Thanks. :P

[Zerzax]

I'll do snare too, it will be fun to code. A week or two after the contest would be a good estimate.

[ZairoN]

Originally Posted by ZairoN

Name: Crippling Strike
Levels: This ability should have 2 different versions and they go on 2 different items.
Function:
Level 1: Has 20% chance to deal 2.25x normal damage and slow the targets attack speed by 15% and movement by 40%.
Level 2: Has 25% chance to deal 2.5x normal damage and slow the targets attack speed by 20% and movement by 50%
Tooltip: Not really needed because its an item ability.
Im not sure if this can be done in GUI effectively, so im gonna say JASS tho GUI would be nice.
MUI not needed because its for a singleplayer rpg.

Is anyone going to make this?

[Zerzax]

EDIT: Just realized it would require attack detection.

[xbadassx]

Originally Posted by Zerzax

Here is Death Grip, non-MUI. It's still an awesome spell, and I intend to at some point make it MUI. I attempted doing this, and I think it was either beyond my scope or just my logic was screwed up, I got very close to fixing the bugs but it never happened and I've got so much going on at the moment. Since I promised a fast return, I'm putting this version up so xbadassx can see what it's like and use it in his map for the time being. The script isn't commented at all, so going to need to fix that at some point, as well as some optimizations.

Non-MUI script:

// Death Grip: Request by xbadassx in The Spell Request Thread at Wc3c.
// Coded by Zerzax
// Uses: TimerUtils and Parabolic Function.

scope DeathGrip initializer init

    globals
        private constant integer SPELL_ID='A000'
        private constant integer FLYING_HEIGHT_HACK='Amrf'
        
        private constant string LIGHTNING_PATH="DRAM"
        private constant string CHANNEL_ANIM="stand channel"
        private constant string GRAB_EFFECTS="Abilities\\Spells\\Human\\MarkOfChaos\\MarkOfChaosTarget.mdl"
        private constant string ATTACH_POINT="origin"
        private constant string END_ANIMATION="stand"
        
        private constant real BASE_LIGHTNING_HEIGHT=50.00
        private constant real MAXIMUM_DISTANCE=1200.00 // the spell cancels at this point
        private constant real MOVE_INTERVAL=0.02
        private constant real MOVE_OFFSET=25.00
        private constant real COLLISION_DISTANCE=16.00
        private constant real MAX_LIGHTNING_HEIGHT=100.00
        private constant real END_DISTANCE=70.00
    endglobals
    
    private function HookOffSet takes nothing returns real
        return 1 * MOVE_OFFSET
    endfunction
    
    private function DrawOffset takes nothing returns real
        return 1 * MOVE_OFFSET
    endfunction
    
    private struct grapple
        unit caster = null
        unit target = null
        timer moveTimer = null
        lightning hook
        
        integer phase=1
        
        real castX = 0 
        real castY = 0 
        real hookX = 0 
        real hookY = 0 
        real targX = 0 
        real targY = 0 
        real cos = 0
        real sin = 0
        
        real totalDist = 0.0
        real currentDist = 0.0
        integer count = 0
        
        boolean pastHijacking = false
        
        method warp takes nothing returns nothing
            set this.phase = 2 
            set this.totalDist = SquareRoot((this.castX - this.hookX)*(this.castX - this.hookX) + (this.castY - this.hookY)*(this.castY - this.hookY))
                
            call DestroyEffect(AddSpellEffectTargetById(SPELL_ID, EFFECT_TYPE_SPECIAL, this.target, ATTACH_POINT))
            call PauseUnit(this.target, true)
            call SetUnitInvulnerable(this.target, true)
            call UnitAddAbility(this.target, FLYING_HEIGHT_HACK)
            call UnitRemoveAbility(this.target, FLYING_HEIGHT_HACK)
            
            set this.cos=-this.cos
            set this.sin=-this.sin
            call SetUnitFacing(this.target, Atan2(this.castY - this.targY, this.castX - this.targX) * bj_RADTODEG )
        endmethod
        
        method pull takes nothing returns boolean
            local real currentZ=ParabolaZ(MAX_LIGHTNING_HEIGHT, this.totalDist, this.currentDist)
            
            set this.currentDist=this.currentDist + MOVE_OFFSET
            set this.targX = this.targX + MOVE_OFFSET * this.cos
            set this.targY = this.targY + MOVE_OFFSET * this.sin
            call SetUnitX(this.target, this.targX)
            call SetUnitY(this.target, this.targY)
            call SetUnitFlyHeight(this.target, currentZ, 0)
            call MoveLightningEx(this.hook, false, this.castX, this.castY, BASE_LIGHTNING_HEIGHT, this.targX, this.targY, currentZ) 
        
            return IsUnitInRangeXY(this.target, this.castX, this.castY, END_DISTANCE)
        endmethod
        
        method throw takes nothing returns boolean
            local real targX=GetUnitX(this.target)
            local real targY=GetUnitY(this.target)
            local real ang
                        
            if targX != this.targX or targY != this.targY then
                set this.targX = targX
                set this.targY = targY
                set ang=Atan2(targY - this.hookY, targX - this.hookX)
                set this.cos=Cos(ang)
                set this.sin=Sin(ang)
                call SetUnitFacing(this.caster, ang * bj_RADTODEG)
            endif
            
            set this.hookX=this.hookX + MOVE_OFFSET * this.cos
            set this.hookY=this.hookY + MOVE_OFFSET * this.sin
            call MoveLightning(this.hook, false, this.castX, this.castY, this.hookX, this.hookY) 
            
            return IsUnitInRangeXY(this.target, this.hookX, this.hookY, COLLISION_DISTANCE)
        endmethod
        
        static method update takes nothing returns nothing
            local grapple g=grapple(GetTimerData(GetExpiredTimer()))
            
            if IsUnitInRangeXY(g.target, g.castX, g.castY, MAXIMUM_DISTANCE) and GetWidgetLife(g.target) > 0.405 and GetWidgetLife(g.caster) > 0.405 then
                if g.phase == 1 and g.throw() then
                    call g.warp()
                elseif g.pull() then
                    call g.destroy()
                endif
            else
                call g.destroy()
            endif
        
        endmethod
    
        static method create takes unit c, unit t returns grapple
            local grapple g=grapple.allocate()
            local real castX=GetUnitX(c)
            local real castY=GetUnitY(c)
            local real ang
            
            set g.caster=c
            set g.target=t
            set g.castX=castX
            set g.castY=castY
            set g.hookX=castX
            set g.hookY=castY
            set g.targX=GetUnitX(t)
            set g.targY=GetUnitY(t) 

            set ang=Atan2(g.targY - castY, g.targX - castX)
            set g.cos=Cos(ang)
            set g.sin=Sin(ang)
            
            if g.hook == null then
                set g.hook=AddLightningEx(LIGHTNING_PATH, false, castX, castY, BASE_LIGHTNING_HEIGHT, castX, castY, BASE_LIGHTNING_HEIGHT)
            endif
            
            call PauseUnit(c, true)
            call SetUnitAnimation(c, CHANNEL_ANIM)
            
            set g.moveTimer=NewTimer()
            call SetTimerData(g.moveTimer, integer(g))
            call TimerStart(g.moveTimer, MOVE_INTERVAL, true, function grapple.update)
        
            return g
        endmethod
        
        method onDestroy takes nothing returns nothing
            call ReleaseTimer(this.moveTimer)
            call MoveLightning(this.hook, false, 0,0,0,0)
            
            call PauseUnit(this.caster, false)
            call SetUnitPosition(this.caster, this.castX, this.castY)
            call SetUnitAnimation(this.caster, END_ANIMATION)
            
            call SetUnitPosition(this.target, this.targX, this.targY)
            call SetUnitFlyHeight(this.target, 0, 0)
            call SetUnitInvulnerable(this.target, false)
            call PauseUnit(this.target, false)
        endmethod
    
    endstruct
    
    private function SpellExecute takes nothing returns nothing
        call grapple.create(GetTriggerUnit(), GetSpellTargetUnit())
    endfunction
    
    private function SpellCondition takes nothing returns boolean
        return GetSpellAbilityId()==SPELL_ID
    endfunction

    private function init takes nothing returns nothing
        local trigger t=CreateTrigger()
        call TriggerAddAction(t, function SpellExecute)
        call TriggerAddCondition(t, Condition(function SpellCondition))
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_SPELL_EFFECT)
    endfunction

endscope

So here you go for now.

The visuals are insane and I love every part the spell. Thank you so much.
But there is a glitch. When the target is running away from the hero, and Death Grip is cast upon the target, it would fly behind the caster inside of stopping at the caster, but other than that I love it!

[ZairoN]

Originally Posted by Zerzax

EDIT: Just realized it would require attack detection.

So that means what?