ARGB - Page 4

Mr.Malte · 09-08-2009, 04:58 PM

But blizzard should know the colors, they gave to players.
These colors always work perfectly for me.

Earth-Fury · 09-08-2009, 06:12 PM

http://www.hiveworkshop.com/forums/498945-post3.html

playercolours taken from the editor's Player Properties dialog.

Skater · 09-08-2009, 07:15 PM

Cyan is actually #1ce6b9 xD
I got it from some file inside the mpq. I can't remember the exact file. Maybe something
with replaceabletextures\teamcolor.
But i still have the list of exact playercolors.

Code:

#  Player			RED	GREEN	BLUE	HEX-CODE


0  PLAYER_COLOR_RED =		255	3	3	ff0303
1  PLAYER_COLOR_BLUE =		0	66	255	0042ff
2  PLAYER_COLOR_CYAN =		28	230	185	1ce6b9
3  PLAYER_COLOR_PURPLE =	84	0	129	540081
4  PLAYER_COLOR_YELLOW =	255	252	1	fffc01
5  PLAYER_COLOR_ORANGE =	254	138	14	fe8a0e
6  PLAYER_COLOR_GREEN =		32	192	0	20c000
7  PLAYER_COLOR_PINK =		229	91	176	e55bb0
8  PLAYER_COLOR_LIGHT_GRAY =	149	150	151	959697
9  PLAYER_COLOR_LIGHT_BLUE =	126	191	241	7ebff1
10 PLAYER_COLOR_AQUA =		16	98	70	106246
11 PLAYER_COLOR_BROWN =		78	42	4	4e2a04

Av3n · 09-15-2009, 07:24 AM

Vex by any chance that you will implement a function to convert a |c00ffffff|r string to an ARGB struct? If not can you post a code that demonstrates it instead?

-Av3n

Drain Pipe · 09-16-2009, 02:27 AM

Alpha doesn't work :/

Anachron · 09-16-2009, 02:02 PM

Quote:

Originally Posted by Drain Pipe

Alpha doesn't work :/

Tried 255? :P

Deaod · 09-16-2009, 04:56 PM

Alpha doesnt work in what context? Where did you use it?

**Vexorian** · 10-27-2009, 02:43 PM

1.2, fixed the player colors, and added fromPlayerColor.

If I remember correctly, I originally took the colors from the first place as Skater. if you had an older version of ARGB you may notice there are a lot of coincidences, apparently I just had a couple of typos when copying, sorry.

**Vexorian** · 10-27-2009, 02:48 PM

Quote:

Originally Posted by Av3n

Vex by any chance that you will implement a function to convert a |c00ffffff|r string to an ARGB struct? If not can you post a code that demonstrates it instead?

-Av3n

I would first have some Table that converts things like "F" and "f" to 15, "A" and "a" to 10, etc.

Then I would use that table to be able to convert "FF" to 15*16+15, etc.

Then splity the string you provided to the function into four couples of hex values, each of these will generate a value from 0 to 255 then use ARGB.create with these values.

**Anitarf** · 11-26-2009, 09:31 PM

Okay, I seem to have stumbled on some weird bug with the ARGBrecolor module used in xefx:

This works (the xefx are of the desired colour):
call charge.fx.recolor(FX_END_COLOUR.red,FX_END_COLOUR.green,FX_END_COLOUR.blue,FX_END_COLOUR.alpha)
And this doesn't (the xefx are invisible):
call charge.fx.ARGBrecolor(FX_END_COLOUR)
I tried making the xefx dummy unit public so I could also test this and it also worked:
call FX_END_COLOUR.recolorUnit(charge.fx.dummy)
I have the latest xefx and ARGB in my map. This line of code is the only one I changed between tests. I have no idea why ARGBrecolor doesn't work because it and recolorUnit seem to be using the exact same code.

Kueken · 12-12-2009, 04:16 PM

So, I just tested this a bit, and should not this:

JASS:

module ARGBrecolor
    method ARGBrecolor takes ARGB color returns nothing
    ...
     local integer col=integer(this)
...

look more like this way?

JASS:

module ARGBrecolor
    method ARGBrecolor takes ARGB color returns nothing
    ...
     local integer col=integer(color)
...

Otherwise, it would convert the struct, in which the module is implemented to a color, or not?
At least, for me some messages showed, col was always the current instance of the struct and not any color, thus it was usually translated to (instance) blue rest 0.
Changing "this" to "color" made it work properly.

This should be exactly the same problem Anitarf mentioned, I tried xefx, and the same error happened, the dummys became invisible. However, changing this to color in ARGBrecolor method fixed this, too.

Or am I using ARGB wrong?

SanKakU · 07-15-2010, 06:38 PM

can you change colors of players and their units with this system? this will include hero glow, right? sounds cool...

Pyrogasm · 08-29-2016, 03:05 AM

Years late and many dollars short but... In case anyone else comes along and tries to use this (like I did), Kueken has correctly identified the error in ARGBrecolor. A fixed version of the library is located below.

Quote:

Originally Posted by Kueken

So, I just tested this a bit, and should not this:

JASS:

module ARGBrecolor
    method ARGBrecolor takes ARGB color returns nothing
    ...
     local integer col=integer(this)
...

look more like this way?

JASS:

module ARGBrecolor
    method ARGBrecolor takes ARGB color returns nothing
    ...
     local integer col=integer(color)
...

Otherwise, it would convert the struct, in which the module is implemented to a color, or not?
At least, for me some messages showed, col was always the current instance of the struct and not any color, thus it was usually translated to (instance) blue rest 0.
Changing "this" to "color" made it work properly.

This should be exactly the same problem Anitarf mentioned, I tried xefx, and the same error happened, the dummys became invisible. However, changing this to color in ARGBrecolor method fixed this, too.

Or am I using ARGB wrong?

ARGB v1.Kueken:

library ARGB initializer init
//******************************************************************************
//*
//* ARGB 1.3, Kueken edit
//* ====
//*  For your color needs.
//*  
//*  An ARGB object is a by-value struct, this means that assigning copies the
//* contents of the struct and that you don't have to use .destroy(), the
//* downside is that you cannot assign its members (can't do set c.r= 123 )
//*
//*  This library should have plenty of uses, for example, if your spell involves
//* some unit recoloring you can allow users to input the color in the config
//* section as 0xAARRGGBB and you can then use this to decode that stuff.
//*
//* You can also easily merge two colors and make fading effects using ARGB.mix
//*
//* There's ARGB.fromPlayer which gets an ARGB object containing the player's
//* color. Then you can use the previous utilities on it.
//*
//* The .str() instance method can recolor a string, and the recolorUnit method
//* will apply the ARGB on a unit
//*
//* For other uses, you can use the .red, .green, .blue and .alpha members to get
//* an ARGB object's color value (from 0 to 255).
//*
//* structs that have a recolor method that takes red,green,blue and alpha as 0.255
//* integers can implement the ARGBrecolor module to gain an ability to quickly
//* recolor using an ARGB object.
//*
//********************************************************************************

//=================================================================================
globals
    private string array i2cc
endglobals

//this double naming stuff is beginning to make me insane, if only TriggerEvaluate() wasn't so slow...
struct ARGB extends array
    static method create takes integer a, integer r, integer g, integer b returns ARGB
        return ARGB(b + g*0x100 + r*0x10000 + a*0x1000000)
    endmethod
    
    // not really part of the exported stuff, I may remove it in the future, so please don't call this textmacro
    //! textmacro ARGB_PLAYER_COLOR_2_ARGB
        if(pc==PLAYER_COLOR_RED) then
            return 0xFFFF0303
        elseif(pc==PLAYER_COLOR_BLUE) then
            return 0xFF0042FF
        elseif(pc==PLAYER_COLOR_CYAN) then
            return 0xFF1CE6B9
        elseif(pc==PLAYER_COLOR_PURPLE) then
            return 0xFF540081
        elseif(pc==PLAYER_COLOR_YELLOW) then
            return 0xFFFFFC01
        elseif(pc==PLAYER_COLOR_ORANGE) then
            return 0xFFFE8A0E
        elseif(pc==PLAYER_COLOR_GREEN) then
            return 0xFF20C000
        elseif(pc==PLAYER_COLOR_PINK) then
            return 0xFFE55BB0
        elseif(pc==PLAYER_COLOR_LIGHT_GRAY) then
            return 0xFF959697
        elseif(pc==PLAYER_COLOR_LIGHT_BLUE) then
            return 0xFF7EBFF1
        elseif(pc==PLAYER_COLOR_AQUA) then
            return 0xFF106246
        elseif(pc==PLAYER_COLOR_BROWN) then
            return 0xFF4E2A04
        endif
        
      return 0xFF111111
    //! endtextmacro
    static method fromPlayerColor takes playercolor pc returns ARGB
        //! runtextmacro ARGB_PLAYER_COLOR_2_ARGB()
    endmethod

    static method fromPlayer takes player p returns ARGB
     local playercolor pc=GetPlayerColor(p)
        //! runtextmacro ARGB_PLAYER_COLOR_2_ARGB()
    endmethod

    method operator alpha takes nothing returns integer
        if( integer(this) <0) then
            return 0x80+(-(-integer(this)+0x80000000))/0x1000000
        else
            return (integer(this))/0x1000000
        endif
    endmethod
    method operator alpha= takes integer na returns ARGB
     local integer a
     local integer r
     local integer g
     local integer b
     local integer col=integer(this)

       if (col<0) then
           set col=-(-col+0x80000000)
           set a=0x80+col/0x1000000
           set col=col-(a-0x80)*0x1000000
       else
           set a=col/0x1000000
           set col=col-a*0x1000000
       endif
       set r=col/0x10000
       set col=col-r*0x10000
       set g=col/0x100
       set b=col-g*0x100
       return ARGB(b + g*0x100 + r*0x10000 + na*0x1000000) 
    endmethod




    method operator red takes nothing returns integer
     local integer c=integer(this)*0x100
        if(c<0) then
            return 0x80+(-(-c+0x80000000))/0x1000000
        else
            return c/0x1000000
        endif
    endmethod
    method operator red= takes integer nr returns ARGB
     local integer a
     local integer r
     local integer g
     local integer b
     local integer col=integer(this)

       if (col<0) then
           set col=-(-col+0x80000000)
           set a=0x80+col/0x1000000
           set col=col-(a-0x80)*0x1000000
       else
           set a=col/0x1000000
           set col=col-a*0x1000000
       endif
       set r=col/0x10000
       set col=col-r*0x10000
       set g=col/0x100
       set b=col-g*0x100
       return ARGB(b + g*0x100 + nr*0x10000 + a*0x1000000) 
    endmethod

    method operator green takes nothing returns integer
     local integer c=integer(this)*0x10000
        if(c<0) then
            return 0x80+(-(-c+0x80000000))/0x1000000
        else
            return c/0x1000000
        endif
    endmethod
    method operator green= takes integer ng returns ARGB
     local integer a
     local integer r
     local integer g
     local integer b
     local integer col=integer(this)

       if (col<0) then
           set col=-(-col+0x80000000)
           set a=0x80+col/0x1000000
           set col=col-(a-0x80)*0x1000000
       else
           set a=col/0x1000000
           set col=col-a*0x1000000
       endif
       set r=col/0x10000
       set col=col-r*0x10000
       set g=col/0x100
       set b=col-g*0x100
       return ARGB(b + ng*0x100 + r*0x10000 + a*0x1000000) 
    endmethod

    //=======================================================
    //
    //
    method operator blue takes nothing returns integer
     local integer c=integer(this)*0x1000000
        if(c<0) then
            return 0x80+(-(-c+0x80000000))/0x1000000
        else
            return c/0x1000000
        endif
    endmethod
    method operator blue= takes integer nb returns ARGB
     local integer a
     local integer r
     local integer g
     local integer b
     local integer col=integer(this)

       if (col<0) then
           set col=-(-col+0x80000000)
           set a=0x80+col/0x1000000
           set col=col-(a-0x80)*0x1000000
       else
           set a=col/0x1000000
           set col=col-a*0x1000000
       endif
       set r=col/0x10000
       set col=col-r*0x10000
       set g=col/0x100
       set b=col-g*0x100
       return ARGB(nb + g*0x100 + r*0x10000 + a*0x1000000) 
    endmethod

    //====================================================================
    // Mixes two colors, s would be a number 0<=s<=1 that determines
    // the weight given to color c2.
    //
    //  mix(c1,c2,0)   = c1
    //  mix(c1,c2,1)   = c2
    //  mix(c1,c2,0.5) = Mixing the colors c1 and c2 in equal proportions.
    //
    static method mix takes ARGB c1, ARGB c2, real s returns ARGB
      //widest function ever
      return ARGB( R2I(c2.blue*s+c1.blue*(1-s)+0.5) + R2I(c2.green*s+c1.green*(1-s)+0.5)*0x100 + R2I(c2.red*s+c1.red*(1-s)+0.5)*0x10000 + R2I(c2.alpha*s+c1.alpha*(1-s)+0.5)*0x1000000)
    endmethod

    method str takes string s returns string
       return "|c"+i2cc[.alpha]+i2cc[.red]+i2cc[.green]+i2cc[.blue]+s+"|r"
    endmethod

    method recolorUnit takes unit u returns nothing
     local integer a
     local integer r
     local integer g
     local integer b
     local integer col=integer(this)

       if (col<0) then
           set col=-(-col+0x80000000)
           set a=0x80+col/0x1000000
           set col=col-(a-0x80)*0x1000000
       else
           set a=col/0x1000000
           set col=col-a*0x1000000
       endif
       set r=col/0x10000
       set col=col-r*0x10000
       set g=col/0x100
       set b=col-g*0x100
       call SetUnitVertexColor(u,r,g,b,a)
    endmethod

endstruct

module ARGBrecolor
    method ARGBrecolor takes ARGB color returns nothing
     local integer a
     local integer r
     local integer g
     local integer b
     local integer col=integer(color)

       if (col<0) then
           set col=-(-col+0x80000000)
           set a=0x80+col/0x1000000
           set col=col-(a-0x80)*0x1000000
       else
           set a=col/0x1000000
           set col=col-a*0x1000000
       endif
       set r=col/0x10000
       set col=col-r*0x10000
       set g=col/0x100
       set b=col-g*0x100
       
       call this.recolor(r, g , b, a)
    endmethod

endmodule

private function init takes nothing returns nothing
 local integer i=0

    // Don't run textmacros you don't own!
    //! textmacro ARGB_CHAR takes int, chr
        set i=0
        loop
            exitwhen i==16
            set i2cc[$int$*16+i]="$chr$"+i2cc[$int$*16+i]
            set i2cc[i*16+$int$]=i2cc[i*16+$int$]+"$chr$"
            set i=i+1
        endloop
    //! endtextmacro
    //! runtextmacro ARGB_CHAR( "0","0")
    //! runtextmacro ARGB_CHAR( "1","1")
    //! runtextmacro ARGB_CHAR( "2","2")
    //! runtextmacro ARGB_CHAR( "3","3")
    //! runtextmacro ARGB_CHAR( "4","4")
    //! runtextmacro ARGB_CHAR( "5","5")
    //! runtextmacro ARGB_CHAR( "6","6")
    //! runtextmacro ARGB_CHAR( "7","7")
    //! runtextmacro ARGB_CHAR( "8","8")
    //! runtextmacro ARGB_CHAR( "9","9")
    //! runtextmacro ARGB_CHAR("10","A")
    //! runtextmacro ARGB_CHAR("11","B")
    //! runtextmacro ARGB_CHAR("12","C")
    //! runtextmacro ARGB_CHAR("13","D")
    //! runtextmacro ARGB_CHAR("14","E")
    //! runtextmacro ARGB_CHAR("15","F")
endfunction

endlibrary

12-12-2009, 04:16 PM	#56
Kueken User Join Date: Mar 2009 Posts: 149	So, I just tested this a bit, and should not this: JASS: module ARGBrecolor method ARGBrecolor takes ARGB color returns nothing ... local integer col=integer(this) ... look more like this way? JASS: module ARGBrecolor method ARGBrecolor takes ARGB color returns nothing ... local integer col=integer(color) ... Otherwise, it would convert the struct, in which the module is implemented to a color, or not? At least, for me some messages showed, col was always the current instance of the struct and not any color, thus it was usually translated to (instance) blue rest 0. Changing "this" to "color" made it work properly. This should be exactly the same problem Anitarf mentioned, I tried xefx, and the same error happened, the dummys became invisible. However, changing this to color in ARGBrecolor method fixed this, too. Or am I using ARGB wrong? Last edited by Kueken : 12-12-2009 at 07:01 PM.

07-15-2010, 06:38 PM	#57
SanKakU User Join Date: Jan 2009 Posts: 136	can you change colors of players and their units with this system? this will include hero glow, right? sounds cool... Last edited by SanKakU : 07-15-2010 at 06:39 PM.

Thread Tools	Search this Thread
Show Printable Version Email this Page	Search this Thread: Advanced Search

09-08-2009, 04:58 PM	#46
Mr.Malte User Join Date: Apr 2008 Posts: 286 Submissions (2)	But blizzard should know the colors, they gave to players. These colors always work perfectly for me.

09-16-2009, 02:27 AM	#50
Drain Pipe User Join Date: May 2006 Posts: 129	Alpha doesn't work :/