Disciple of Life Spellpack

Deaod · 12-24-2009, 11:52 PM

Well, heres a little spellpack i started 12 hours before the deadline of the fourth hero contest. Needless to say that i didnt finish until today. Its still missing the item, but whatever.

I am proud to present to you the Disciple of Life, a supporting hero with a bit of a nuke side.

The spells themselves are rather unoriginal, i admit. Then again, i havent seen many submissions using DamageModifiers yet, so these may be a good demonstration.

First off: I used custom icons, because none of the Blizzard ones fit decently (imo). One of those icons is from WoW, i take permission as a given for that icon.
As for the other three icons, heres the permission:

Hidden information:

These spells use:

vJass
AutoIndex
GroupUtils
SpellEvent
- Table
DamageModifiers
- DamageEvent, as it is currently the only library that supports DamageModifiers.
IntuitiveBuffSystem
TimedHandles (optionally, the spells can be configured to not require it)

Credits

Changelog

And here are the spells:

Seed of Life

Learn Tooltip

Spell Code:

library SeedOfLife initializer Init uses GroupUtils, DamageModifiers, SpellEvent, AutoIndex, IntuitiveBuffSystem, optional TimedHandles
    
    private keyword Data // DO NOT TOUCH!
    
    globals
        private constant    integer                 AID                         = 'A001' // ability triggering this. Any unit targeting ability is fine. Used Bloodlust
        private constant    integer                 BUFF_PLACER_AID             = 'A004' // Ability placing BID on the unit this ability is added to. Based off of Slow Aura (Tornado).
        private constant    integer                 BID                         = 'B000' // buff placed by BUFF_PLACER_AID on the target unit
        private constant    string                  FX                          = "Abilities\\Spells\\Human\\Heal\\HealTarget.mdl" // displayed on the target unit when the effect of this ability is triggered.
        private constant    string                  FX_ATTPT                    = "origin"
        private constant    real                    FX_DURATION                 = 1.833 // 0 or less only plays the death animation // ignored if TimedHandles is not present in the map
        private constant    string                  TARGET_FX                   = "" // displayed on the target of this spell
        private constant    string                  TARGET_FX_ATTPT             = "" // where to display the effect on the target of this spell
        private constant    integer                 PRIORITY                    = 0 // when to trigger the effects of an instance of this spell when a unit receives damage // refer to DamageModifiers documentation
        private             real            array   DURATION                    // how long does the buff last?
        private             real            array   AOE                         // Heals all units around the damaged target in this area
        private             real            array   CHANCE                      // Chance to trigger this ability // 1.0 = 100% // 0.0 = 0%
        private             integer         array   MAX_HEALINGS                // heal at most this many times // zero or less for no limit
    endglobals
    
    // how long does the buff last?
    private function Duration takes integer level returns real
        return DURATION[level]
    endfunction
    
    // Heals all units around the damaged target in this area
    private function Aoe takes integer level returns real
        return AOE[level]
    endfunction
    
    // Chance to trigger this ability // 1.0 = 100% // 0.0 = 0%
    private function Chance takes integer level returns real
        return CHANCE[level]
    endfunction
    
    // heal at most this many times // zero or less for no limit
    private function Max_Healings takes integer level returns integer
        return MAX_HEALINGS[level]
    endfunction
    
    private function SetUpSpellData takes nothing returns nothing
        // how long does the buff last?
        set DURATION[1]=7
        set DURATION[2]=7
        set DURATION[3]=7
        
        // Heals all units around the damaged target in this area
        set AOE[1]=200
        set AOE[2]=275
        set AOE[3]=350
        
        // Chance to trigger this ability // 1.0 = 100% // 0.0 = 0%
        set CHANCE[1]=1
        set CHANCE[2]=1
        set CHANCE[3]=1
        
        // heal at most this many times // zero or less for no limit
        set MAX_HEALINGS[1]=0
        set MAX_HEALINGS[2]=0
        set MAX_HEALINGS[3]=0
    endfunction
    
    // if you want to get the targets current HP, use GetUnitLife(whichUnit)
    
    // damage dealt to a unit with this buff active needs to be greater than what this function returns to be blocked
    private function Minimum_Damage takes integer level, unit target returns real
        return 0.
    endfunction
    
    // how much damage to block
    private function Damage_Blocked takes integer level, unit target, real damage returns real
        return 0.
    endfunction
    
    // how much health to restore after blocking
    private function Health_Restored takes integer level, unit target, real damage returns real
        return 10.+level*10.
    endfunction
    
    // how much health to heal units in the area
    private function Aoe_Heal takes integer level, unit target, real damage returns real
        return 10.+level*5.
    endfunction
    
    // only units matching these criteria will get healed
    private function ValidTarget takes unit u, unit caster returns boolean
        return     IsUnitAlly(u, GetOwningPlayer(caster))/*
            */ and IsUnitType(u, UNIT_TYPE_MECHANICAL)==false/*
            */ and IsUnitType(u, UNIT_TYPE_STRUCTURE)==false/*
            */ and IsUnitType(u, UNIT_TYPE_MAGIC_IMMUNE)==false/*
            */
    endfunction
    
    //
    
    globals
        private integer BuffType
    endglobals
    
    private struct Data extends DamageModifier
        unit caster
        unit target
        effect targetFx
        integer level
        integer healings=0
        
        static thistype Tmps
        static real CurrentDamage
        
        static thistype array Instance
        
        private method onDestroy takes nothing returns nothing
            set Instance[GetUnitId(.target)]=0
            set .caster=null
            set .target=null
            if TARGET_FX!="" then
                call DestroyEffect(.targetFx)
                set .targetFx=null
            endif
        endmethod
        
        private static method AoeHealEnum takes nothing returns boolean
        local unit u=GetFilterUnit()
            if u!=.Tmps.target and ValidTarget(u, .Tmps.caster) then
                call SetUnitLife(u, GetUnitLife(u)+Aoe_Heal(.Tmps.level, .Tmps.target, .CurrentDamage))
                static if LIBRARY_TimedHandles then
                    if FX_DURATION>0 then
                        call DestroyEffectTimed(AddSpecialEffectTarget(FX, u, FX_ATTPT), FX_DURATION)
                    else
                        call DestroyEffect(AddSpecialEffectTarget(FX, u, FX_ATTPT))
                    endif
                else
                    call DestroyEffect(AddSpecialEffectTarget(FX, u, FX_ATTPT))
                endif
            endif
            set u=null
            return false
        endmethod
        
        private method onDamageTaken takes unit origin, real damage returns real
        local real blocked=0
            if GetRandomReal(0,1)<=Chance(.level) and damage+0.406>=Minimum_Damage(.level, .target) then
                if ValidTarget(.target, .caster) then
                    call SetUnitLife(.target, GetUnitLife(.target)+Health_Restored(.level, .target, damage))
                    static if LIBRARY_TimedHandles then
                        if FX_DURATION>0 then
                            call DestroyEffectTimed(AddSpecialEffectTarget(FX, .target, FX_ATTPT), FX_DURATION)
                        else
                            call DestroyEffect(AddSpecialEffectTarget(FX, .target, FX_ATTPT))
                        endif
                    else
                        call DestroyEffect(AddSpecialEffectTarget(FX, .target, FX_ATTPT))
                    endif
                    set blocked=Damage_Blocked(.level, .target, damage)
                endif
                if Aoe(.level)>0. then
                    set .Tmps=this
                    set .CurrentDamage=damage
                    call GroupEnumUnitsInArea(ENUM_GROUP, GetUnitX(.target), GetUnitY(.target), Aoe(.level), Condition(function thistype.AoeHealEnum))
                endif
                set .healings=.healings+1
                if Max_Healings(.level)>0 and .healings>=Max_Healings(.level) then
                    call UnitRemoveBuff(.target, BuffType)
                endif
                return -blocked
            endif
            return 0.
        endmethod
        
        static method create takes unit caster, unit target returns thistype
        local thistype s=Instance[GetUnitId(target)]
            if s==0 then
                set s=.allocate(target, PRIORITY)
                set s.caster=caster
                set s.target=target
                if TARGET_FX!="" then
                    set s.targetFx=AddSpecialEffectTarget(TARGET_FX, target, TARGET_FX_ATTPT)
                endif
                set s.level=GetUnitAbilityLevel(caster, AID)
                set Instance[GetUnitId(target)]=s
            else
                if s.level<GetUnitAbilityLevel(caster, AID) then
                    set s.caster=caster
                    set s.healings=0
                    set s.level=GetUnitAbilityLevel(caster, AID)
                endif
            endif
            set UnitAddBuff(caster, target, BuffType, Duration(s.level), s.level).data=s
            return s
        endmethod
        
        static method BuffRemoved takes nothing returns nothing
            call thistype(GetEventBuff().data).destroy()
        endmethod
    endstruct
    
    private function CastResponse takes nothing returns nothing
        call Data.create(SpellEvent.CastingUnit, SpellEvent.TargetUnit)
    endfunction
    
    private function Init takes nothing returns nothing
        call RegisterSpellEffectResponse(AID, CastResponse)
        
        set BuffType=DefineBuffType(BUFF_PLACER_AID, BID, 0, false, true, 0,0,Data.BuffRemoved)
        
        call SetUpSpellData()
    endfunction
    
endlibrary

Prolonged Life

Learn Tooltip

Spell Code:

library ProlongedLife initializer Init uses GroupUtils, DamageModifiers, SpellEvent, AutoIndex, IntuitiveBuffSystem, optional TimedHandles
    
    private keyword Data // DO NOT TOUCH!
    
    globals
        private constant    integer                 AID                         = 'A000' // ability triggering this. Any unit targeting ability is fine. Used Channel
        private constant    integer                 BUFF_PLACER_AID             = 'A005' // Ability placing BID on the unit this ability is added to. Based off of Slow Aura (Tornado).
        private constant    integer                 BID                         = 'B001' // buff placed by BUFF_PLACER_AID on the target unit
        private constant    string                  FX                          = "Abilities\\Spells\\Items\\AIre\\AIreTarget.mdl" // displayed on the target unit when the effect of this ability is triggered.
        private constant    string                  FX_ATTPT                    = "origin"
        private constant    real                    FX_DURATION                 = 0. // 0 or less only plays the death animation // ignored if TimedHandles is not present in the map
        private constant    string                  TARGET_FX                   = "Abilities\\Spells\\Items\\HealingSalve\\HealingSalveTarget.mdl" // displayed on the target of this spell
        private constant    string                  TARGET_FX_ATTPT             = "head" // where to display the effect on the target of this spell
        private constant    integer                 PRIORITY                    = 0 // when to trigger the effects of an instance of this spell when a unit receives damage // refer to DamageModifiers documentation
        private             real            array   DURATION                    // how long does the buff last?
        private             real            array   AOE                         // Heals all units around the damaged target in this area
        private             real            array   CHANCE                      // Chance to trigger this ability // 1.0 = 100% // 0.0 = 0%
        private             integer         array   MAX_HEALINGS                // heal at most this many times // zero or less for no limit
    endglobals
    
    // how long does the buff last?
    private function Duration takes integer level returns real
        return DURATION[level]
    endfunction
    
    // Heals all units around the damaged target in this area
    private function Aoe takes integer level returns real
        return AOE[level]
    endfunction
    
    // Chance to trigger this ability // 1.0 = 100% // 0.0 = 0%
    private function Chance takes integer level returns real
        return CHANCE[level]
    endfunction
    
    // heal at most this many times // zero or less for no limit
    private function Max_Healings takes integer level returns integer
        return MAX_HEALINGS[level]
    endfunction
    
    private function SetUpSpellData takes nothing returns nothing
        // how long does the buff last?
        set DURATION[1]=8
        set DURATION[2]=8
        set DURATION[3]=8
        
        // Heals all units around the damaged target in this area
        set AOE[1]=0
        set AOE[2]=0
        set AOE[3]=0
        
        // Chance to trigger this ability // 1.0 = 100% // 0.0 = 0%
        set CHANCE[1]=1
        set CHANCE[2]=1
        set CHANCE[3]=1
        
        // heal at most this many times // zero or less for no limit
        set MAX_HEALINGS[1]=1
        set MAX_HEALINGS[2]=1
        set MAX_HEALINGS[3]=1
    endfunction
    
    // if you want to get the targets current HP, use GetUnitLife(whichUnit)
    
    // damage dealt to a unit with this buff active needs to be greater than what this function returns to be blocked
    private function Minimum_Damage takes integer level, unit target returns real
        return GetUnitLife(target)
    endfunction
    
    // how much damage to block
    private function Damage_Blocked takes integer level, unit target, real damage returns real
        return damage
    endfunction
    
    // how much health to restore after blocking
    private function Health_Restored takes integer level, unit target, real damage returns real
        return GetUnitLife(target)*0.1*level
    endfunction
    
    // how much health to heal units in the area
    private function Aoe_Heal takes integer level, unit target, real damage returns real
        return 0.
    endfunction
    
    // only units matching these criteria will get healed
    private function ValidTarget takes unit u, unit caster returns boolean
        return     IsUnitAlly(u, GetOwningPlayer(caster))/*
            */ and IsUnitType(u, UNIT_TYPE_MECHANICAL)==false/*
            */ and IsUnitType(u, UNIT_TYPE_STRUCTURE)==false/*
            */ and IsUnitType(u, UNIT_TYPE_MAGIC_IMMUNE)==false/*
            */
    endfunction
    
    //
    
    globals
        private integer BuffType
    endglobals
    
    private struct Data extends DamageModifier
        unit caster
        unit target
        effect targetFx
        integer level
        integer healings=0
        
        static thistype Tmps
        static real CurrentDamage
        
        static thistype array Instance
        
        private method onDestroy takes nothing returns nothing
            set Instance[GetUnitId(.target)]=0
            set .caster=null
            set .target=null
            if TARGET_FX!="" then
                call DestroyEffect(.targetFx)
                set .targetFx=null
            endif
        endmethod
        
        private static method AoeHealEnum takes nothing returns boolean
        local unit u=GetFilterUnit()
            if u!=.Tmps.target and ValidTarget(u, .Tmps.caster) then
                call SetUnitLife(u, GetUnitLife(u)+Aoe_Heal(.Tmps.level, .Tmps.target, .CurrentDamage))
                static if LIBRARY_TimedHandles then
                    if FX_DURATION>0 then
                        call DestroyEffectTimed(AddSpecialEffectTarget(FX, u, FX_ATTPT), FX_DURATION)
                    else
                        call DestroyEffect(AddSpecialEffectTarget(FX, u, FX_ATTPT))
                    endif
                else
                    call DestroyEffect(AddSpecialEffectTarget(FX, u, FX_ATTPT))
                endif
            endif
            set u=null
            return false
        endmethod
        
        private method onDamageTaken takes unit origin, real damage returns real
        local real blocked=0
            if GetRandomReal(0,1)<=Chance(.level) and damage+0.406>=Minimum_Damage(.level, .target) then
                if ValidTarget(.target, .caster) then
                    call SetUnitLife(.target, GetUnitLife(.target)+Health_Restored(.level, .target, damage))
                    static if LIBRARY_TimedHandles then
                        if FX_DURATION>0 then
                            call DestroyEffectTimed(AddSpecialEffectTarget(FX, .target, FX_ATTPT), FX_DURATION)
                        else
                            call DestroyEffect(AddSpecialEffectTarget(FX, .target, FX_ATTPT))
                        endif
                    else
                        call DestroyEffect(AddSpecialEffectTarget(FX, .target, FX_ATTPT))
                    endif
                    set blocked=Damage_Blocked(.level, .target, damage)
                endif
                if Aoe(.level)>0. then
                    set .Tmps=this
                    set .CurrentDamage=damage
                    call GroupEnumUnitsInArea(ENUM_GROUP, GetUnitX(.target), GetUnitY(.target), Aoe(.level), Condition(function thistype.AoeHealEnum))
                endif
                set .healings=.healings+1
                if Max_Healings(.level)>0 and .healings>=Max_Healings(.level) then
                    call UnitRemoveBuff(.target, BuffType)
                endif
                return -blocked
            endif
            return 0.
        endmethod
        
        static method create takes unit caster, unit target returns thistype
        local thistype s=Instance[GetUnitId(target)]
            if s==0 then
                set s=.allocate(target, PRIORITY)
                set s.caster=caster
                set s.target=target
                if TARGET_FX!="" then
                    set s.targetFx=AddSpecialEffectTarget(TARGET_FX, target, TARGET_FX_ATTPT)
                endif
                set s.level=GetUnitAbilityLevel(caster, AID)
                set Instance[GetUnitId(target)]=s
            else
                if s.level<GetUnitAbilityLevel(caster, AID) then
                    set s.caster=caster
                    set s.healings=0
                    set s.level=GetUnitAbilityLevel(caster, AID)
                endif
            endif
            set UnitAddBuff(caster, target, BuffType, Duration(s.level), s.level).data=s
            return s
        endmethod
        
        static method BuffRemoved takes nothing returns nothing
            call thistype(GetEventBuff().data).destroy()
        endmethod
    endstruct
    
    private function CastResponse takes nothing returns nothing
        call Data.create(SpellEvent.CastingUnit, SpellEvent.TargetUnit)
    endfunction
    
    private function Init takes nothing returns nothing
        call RegisterSpellEffectResponse(AID, CastResponse)
        
        set BuffType=DefineBuffType(BUFF_PLACER_AID, BID, 0, false, true, 0,0,Data.BuffRemoved)
        
        call SetUpSpellData()
    endfunction
    
endlibrary

Smiting Zeal

Learn Tooltip

Spell Code:

library SmitingZeal initializer Init uses SpellEvent, GroupUtils
    
    globals
        private constant    integer                 AID                         = 'A002' // any passive ability should do fine, preferably one that doesnt place a buff.
        private constant    string                  DAMAGE_FX                   = "Abilities\\Spells\\Human\\Feedback\\SpellBreakerAttack.mdl" // effect displayed when a unit gets damaged by this ability
        private constant    string                  DAMAGE_FX_ATTPT             = "overhead" // where to display the effect
        private constant    attacktype              ATTACK_TYPE                 = ATTACK_TYPE_MAGIC // what type of damage is dealt to enemy units surrounding the caster (magic, physical, pure, ...)
        private constant    damagetype              DAMAGE_TYPE                 = DAMAGE_TYPE_MAGIC // what type of damage is dealt to enemy units surrounding the caster (magic, physical, pure, ...)
        private constant    weapontype              WEAPON_TYPE                 = WEAPON_TYPE_WHOKNOWS // sound played when a unit is damaged by this ability, WHOKNOWS or null for no sound.
        private             real            array   AOE                         // enemy units within this radius get damaged
        private             real            array   MANA_COST                   // this ability drains this much additional mana from the caster, values >0 but <1 are values relative to the maximum mana of the caster
        private constant    boolean                 ENFORCE_MANA_COST           = false // if true, the effects of this ability will only be triggered if the hero has enough mana,
                                                                                        // if false, it will be triggered whether or not the caster has enough mana, and if he doesnt,
                                                                                        // it will subtract the remaining mana points
    endglobals
    
    private function Aoe takes integer level returns real
        return AOE[level]
    endfunction
    
    private function Mana_Cost takes integer level returns real
        return MANA_COST[level]
    endfunction
    
    private function Damage takes unit caster, integer level returns real
        return GetHeroInt(caster, true)*(1.+level)
    endfunction
    
    private function SetUpSpellData takes nothing returns nothing
        set AOE[1]=300.
        set AOE[2]=375.
        set AOE[3]=450.
        
        set MANA_COST[1]=20.
        set MANA_COST[2]=20.
        set MANA_COST[3]=20.
    endfunction
    
    private function ValidateTarget takes unit u, unit caster returns boolean
        return     IsUnitEnemy(u, GetOwningPlayer(caster))/*
            */ and IsUnitType(u, UNIT_TYPE_DEAD)==false/*
            */ and IsUnitType(u, UNIT_TYPE_STRUCTURE)==false/*
            */ and IsUnitType(u, UNIT_TYPE_MECHANICAL)==false/*
            */ and IsUnitType(u, UNIT_TYPE_MAGIC_IMMUNE)==false/*
            */ and IsUnitVisible(u, GetOwningPlayer(caster))/*
            */
    endfunction
    
    //
    
    globals
        private boolexpr DamageFilter
        private real tmpdam
    endglobals
    
    private function DamageFilterFunc takes nothing returns boolean
    local unit u=GetFilterUnit()
        if ValidateTarget(u, SpellEvent.CastingUnit) then
            call UnitDamageTarget(SpellEvent.CastingUnit, u, tmpdam, true, true, ATTACK_TYPE, DAMAGE_TYPE, WEAPON_TYPE)
            call DestroyEffect(AddSpecialEffectTarget(DAMAGE_FX, u, DAMAGE_FX_ATTPT))
        endif
        set u=null
        return false
    endfunction
    
    private function CastResponse takes nothing returns nothing
    local integer level = GetUnitAbilityLevel(SpellEvent.CastingUnit, AID)
    local real cost=0
        if level>0 then
            if Mana_Cost(level)>=1 then
                set cost=Mana_Cost(level)
            elseif Mana_Cost(level)>0 then
                set cost=Mana_Cost(level)*GetUnitState(SpellEvent.CastingUnit, UNIT_STATE_MANA)
            endif
            if not ENFORCE_MANA_COST or GetUnitState(SpellEvent.CastingUnit, UNIT_STATE_MANA)>=cost then
                call SetUnitState(SpellEvent.CastingUnit, UNIT_STATE_MANA, RMaxBJ(GetUnitState(SpellEvent.CastingUnit, UNIT_STATE_MANA)-Mana_Cost(level), 0))
                set tmpdam=Damage(SpellEvent.CastingUnit, level)
                call GroupEnumUnitsInArea(ENUM_GROUP, GetUnitX(SpellEvent.CastingUnit), GetUnitY(SpellEvent.CastingUnit), Aoe(level), DamageFilter)
            endif
        endif
    endfunction
    
    private function Init takes nothing returns nothing
        call RegisterSpellEffectResponse(0, CastResponse)
        
        set DamageFilter=Condition(function DamageFilterFunc)
        
        call SetUpSpellData()
    endfunction
    
endlibrary

Reverse Damage

Learn Tooltip

Spell Code:

library ReverseDamage initializer Init uses GroupUtils, DamageModifiers, SpellEvent, AutoIndex, IntuitiveBuffSystem, optional TimedHandles
    
    private keyword Data // DO NOT TOUCH!
    
    globals
        private constant    integer                 AID                         = 'A003' // ability triggering this. Any unit targeting ability is fine. Used Bloodlust
        private constant    integer                 BUFF_PLACER_AID             = 'A006' // Ability placing BID on the unit this ability is added to. Based off of Slow Aura (Tornado).
        private constant    integer                 BID                         = 'B002' // buff placed by BUFF_PLACER_AID on the target unit
        private constant    string                  FX                          = "Abilities\\Spells\\Undead\\ReplenishHealth\\ReplenishHealthCasterOverhead.mdl" // displayed on the target unit when the effect of this ability is triggered.
        private constant    string                  FX_ATTPT                    = "head"
        private constant    real                    FX_DURATION                 = 0. // 0 or less only plays the death animation // ignored if TimedHandles is not present in the map
        private constant    string                  TARGET_FX                   = "Abilities\\Spells\\Items\\HealingSalve\\HealingSalveTarget.mdl" // displayed on the target of this spell
        private constant    string                  TARGET_FX_ATTPT             = "head" // where to display the effect on the target of this spell
        private constant    integer                 PRIORITY                    = 0 // when to trigger the effects of an instance of this spell when a unit receives damage // refer to DamageModifiers documentation
        private             real            array   DURATION                    // how long does the buff last?
        private             real            array   AOE                         // Heals all units around the damaged target in this area
        private             real            array   CHANCE                      // Chance to trigger this ability // 1.0 = 100% // 0.0 = 0%
        private             integer         array   MAX_HEALINGS                // heal at most this many times // zero or less for no limit
    endglobals
    
    // how long does the buff last?
    private function Duration takes integer level returns real
        return DURATION[level]
    endfunction
    
    // Heals all units around the damaged target in this area
    private function Aoe takes integer level returns real
        return AOE[level]
    endfunction
    
    // Chance to trigger this ability // 1.0 = 100% // 0.0 = 0%
    private function Chance takes integer level returns real
        return CHANCE[level]
    endfunction
    
    // heal at most this many times // zero or less for no limit
    private function Max_Healings takes integer level returns integer
        return MAX_HEALINGS[level]
    endfunction
    
    private function SetUpSpellData takes nothing returns nothing
        // how long does the buff last?
        set DURATION[1]=5
        set DURATION[2]=5
        set DURATION[3]=5
        
        // Heals all units around the damaged target in this area
        set AOE[1]=0
        set AOE[2]=0
        set AOE[3]=0
        
        // Chance to trigger this ability // 1.0 = 100% // 0.0 = 0%
        set CHANCE[1]=1
        set CHANCE[2]=1
        set CHANCE[3]=1
        
        // heal at most this many times // zero or less for no limit
        set MAX_HEALINGS[1]=1
        set MAX_HEALINGS[2]=1
        set MAX_HEALINGS[3]=1
    endfunction
    
    // if you want to get the targets current HP, use GetUnitLife(whichUnit)
    
    // damage dealt to a unit with this buff active needs to be greater than what this function returns to be blocked
    private function Minimum_Damage takes integer level, unit target returns real
        return 20.
    endfunction
    
    // how much damage to block
    private function Damage_Blocked takes integer level, unit target, real damage returns real
        return RMinBJ(damage, 100.)
    endfunction
    
    // how much health to restore after blocking
    private function Health_Restored takes integer level, unit target, real damage returns real
        return RMinBJ(damage, 100.)
    endfunction
    
    // how much health to heal units in the area
    private function Aoe_Heal takes integer level, unit target, real damage returns real
        return 0.
    endfunction
    
    // only units matching these criteria will get healed
    private function ValidTarget takes unit u, unit caster returns boolean
        return     IsUnitAlly(u, GetOwningPlayer(caster))/*
            */ and IsUnitType(u, UNIT_TYPE_MECHANICAL)==false/*
            */ and IsUnitType(u, UNIT_TYPE_STRUCTURE)==false/*
            */ and IsUnitType(u, UNIT_TYPE_MAGIC_IMMUNE)==false/*
            */
    endfunction
    
    //
    
    globals
        private integer BuffType
    endglobals
    
    private struct Data extends DamageModifier
        unit caster
        unit target
        effect targetFx
        integer level
        integer healings=0
        
        static thistype Tmps
        static real CurrentDamage
        
        static thistype array Instance
        
        private method onDestroy takes nothing returns nothing
            set Instance[GetUnitId(.target)]=0
            set .caster=null
            set .target=null
            if TARGET_FX!="" then
                call DestroyEffect(.targetFx)
                set .targetFx=null
            endif
        endmethod
        
        private static method AoeHealEnum takes nothing returns boolean
        local unit u=GetFilterUnit()
            if u!=.Tmps.target and ValidTarget(u, .Tmps.caster) then
                call SetUnitLife(u, GetUnitLife(u)+Aoe_Heal(.Tmps.level, .Tmps.target, .CurrentDamage))
                static if LIBRARY_TimedHandles then
                    if FX_DURATION>0 then
                        call DestroyEffectTimed(AddSpecialEffectTarget(FX, u, FX_ATTPT), FX_DURATION)
                    else
                        call DestroyEffect(AddSpecialEffectTarget(FX, u, FX_ATTPT))
                    endif
                else
                    call DestroyEffect(AddSpecialEffectTarget(FX, u, FX_ATTPT))
                endif
            endif
            set u=null
            return false
        endmethod
        
        private method onDamageTaken takes unit origin, real damage returns real
        local real blocked=0
            if GetRandomReal(0,1)<=Chance(.level) and damage+0.406>=Minimum_Damage(.level, .target) then
                if ValidTarget(.target, .caster) then
                    call SetUnitLife(.target, GetUnitLife(.target)+Health_Restored(.level, .target, damage))
                    static if LIBRARY_TimedHandles then
                        if FX_DURATION>0 then
                            call DestroyEffectTimed(AddSpecialEffectTarget(FX, .target, FX_ATTPT), FX_DURATION)
                        else
                            call DestroyEffect(AddSpecialEffectTarget(FX, .target, FX_ATTPT))
                        endif
                    else
                        call DestroyEffect(AddSpecialEffectTarget(FX, .target, FX_ATTPT))
                    endif
                    set blocked=Damage_Blocked(.level, .target, damage)
                endif
                if Aoe(.level)>0. then
                    set .Tmps=this
                    set .CurrentDamage=damage
                    call GroupEnumUnitsInArea(ENUM_GROUP, GetUnitX(.target), GetUnitY(.target), Aoe(.level), Condition(function thistype.AoeHealEnum))
                endif
                set .healings=.healings+1
                if Max_Healings(.level)>0 and .healings>=Max_Healings(.level) then
                    call UnitRemoveBuff(.target, BuffType)
                endif
                return -blocked
            endif
            return 0.
        endmethod
        
        static method create takes unit caster, unit target returns thistype
        local thistype s=Instance[GetUnitId(target)]
            if s==0 then
                set s=.allocate(target, PRIORITY)
                set s.caster=caster
                set s.target=target
                if TARGET_FX!="" then
                    set s.targetFx=AddSpecialEffectTarget(TARGET_FX, target, TARGET_FX_ATTPT)
                endif
                set s.level=GetUnitAbilityLevel(caster, AID)
                set Instance[GetUnitId(target)]=s
            else
                if s.level<GetUnitAbilityLevel(caster, AID) then
                    set s.caster=caster
                    set s.healings=0
                    set s.level=GetUnitAbilityLevel(caster, AID)
                endif
            endif
            set UnitAddBuff(caster, target, BuffType, Duration(s.level), s.level).data=s
            return s
        endmethod
        
        static method BuffRemoved takes nothing returns nothing
            call thistype(GetEventBuff().data).destroy()
        endmethod
    endstruct
    
    private function CastResponse takes nothing returns nothing
        call Data.create(SpellEvent.CastingUnit, SpellEvent.TargetUnit)
    endfunction
    
    private function Init takes nothing returns nothing
        call RegisterSpellEffectResponse(AID, CastResponse)
        
        set BuffType=DefineBuffType(BUFF_PLACER_AID, BID, 0, false, true, 0,0,Data.BuffRemoved)
        
        call SetUpSpellData()
    endfunction
    
endlibrary

Kam · 12-25-2009, 02:28 AM

Nice spells, I like the idea of a support damage hero.

The seed of life was my favorite.

Deaod · 12-28-2009, 03:00 PM

Version 1.0.1

Just noticed that another extension to the Hero Contest was granted. This is really unfortunate.

**Anitarf** · 02-04-2010, 09:22 PM

All/most spells:

The way you code the buff using a WC3 buff spell and then checking periodically if it is still there is very inelegant. An entirely triggered buff would be preferred.
TimedHandles could be made into an optional requirement.
The redundancy in the calibration section is a bit excessive. Either make your calibration array-based or function-based, not both.
If you make it array-based, there is no need for each property to have its own calibration function.
The spell documentation should state that the base spell is expected to be a single target buff spell (or whatever it is expected to be). Just naming two constants AID and BID is not particularly descriptive. In general, the calibration sections could use better documentation.
The spells are quite simple.

Seed of Life:

u!=s.target This should not be a part of the calibration function, but a part of the code, since the unit does in fact get healed, you just do it through the damage modifier instead of through the GroupEnum. (there is no particular reason for this complication, though)

Prolonged Life:

Considering you cleanup the damage modifier in the damage callback anyway, the whole periodic checking is not really needed.

Smiting Zeal:

Here is where I think function-based calibration beats array-based: it makes it easy for the user to either have attribute-based or absolute damage values simply by editing the formula. In your case, as long as the caster is a hero, the calibration only allows attribute-based damage.

Reverse damage:

Considering you cleanup the damage modifier in the damage callback anyway, the whole periodic checking is not really needed.

Deaod · 02-04-2010, 10:50 PM

Quote:

The way you code the buff using a WC3 buff spell and then checking periodically if it is still there is very inelegant. An entirely triggered buff would be preferred.

My thinking was that native WC3 buffs can be purged, something you cant do with auras (Tornado Slow Aura is the base for triggered buffs, right?)Will be done

Quote:

TimedHandles could be made into an optional requirement.

What do you mean, coding the delayed destruction myself?

Quote:

The redundancy in the calibration section is a bit excessive. Either make your calibration array-based or function-based, not both.

I know a lot of people prefer function calibration. I just wanted to make transition between each way easier. Ill move all SetUp functions into a single one, though.

Quote:

The spell documentation should state that the base spell is expected to be a single target buff spell (or whatever it is expected to be). Just naming two constants AID and BID is not particularly descriptive. In general, the calibration sections could use better documentation.

Okay, gonna add a few sentences.

Quote:

This should not be a part of the calibration function, but a part of the code

Okay, will change that. Btw, i remember not healing the target of Seed of Life separately. I also remember that that led to certain bugs, so that distinction is necessary.

Quote:

Considering you cleanup the damage modifier in the damage callback anyway, the whole periodic checking is not really needed.

There are certain situations (ie. the user removes/kill a target of Prolonged Life), where not checking periodically would leak the instance of Prolonged Life. Same applies to Reverse Damage.

@Smiting Zeal: Ill see what i can do to improve it.

Thanks for the review.

Deaod · 01-25-2011, 01:37 PM

Version 1.1.0

**Anitarf** · 01-25-2011, 09:41 PM

Seed of life

The ValidHealTarget function, being a calibration function, should not take an argument of type Data since that's part of internal spell code and not necessarily understandable to someone doing the calibrating. Instead, the function should take the casting unit of the spell as an argument directly (as well as other Data members, like level, if needed).
I am not sure this spell really requires a damage modifier, since it is thematically a healing spell rather than a damage modifying spell. Damage modifying spells restore the unit's life in order to make it seem like the damage was modified, so they must consider all sorts of special cases. Healing spells just restore the unit's life; there's no other requirement, so using a damage modifier for a healing spell seems like overkill, you could just use a regular damage event instead. (however, if you do end up using DamageModifiers anyway, you should use The SetUnitLife and GetUnitLife functions provided by that library instead of SetWidgetLife because other units in range could already be taking damage at that time)
When I suggested you didn't need the periodic checks, I did not realize units could die without taking damage, in which case, as you note, the spell will leak a damage modifier. This is not just a problem with mapmakers using RemoveUnit or KillUnit, it could also happen when summoned unit timers expire. This should still be avoidable without the need for periodic checks. One method would be to utilize AutoIndex's AutoDestroy feature.(I realize now you already use this solution for this spell; why can't you do the same thing for the other two spells that have this problem?) Another method would be to use a system like ABuff instead of a DamageModifier, which would also address my other point about DamageModifiers being an overkill, since ABuff uses a simple damage event.
Minor comment: something like SetUpSpellData might make a for a more descriptive function name than SetUpArrays.

Prolonged Life

Similar comments to above. I suppose damage modifiers are more justified here, since the spell does thematically block an attack, but at the same time it does also restore the unit's life so it's also a healing spell in addition to being a damage blocking spell. Maybe the code should reflect that by blocking the damage using the return value of the onDamageTaken method while restoring the rest of the unit's life by using SetUnitLife. The reason I feel that this distinction is important is because modifying the damage into the negative using DamageModifiers won't just heal the unit, it will also change the damage value for any damage callbacks that run afterwards, so it might seem like the attacker is healing the target when in fact it's the prolong life spell that's doing it, the attacker is just having its damage blocked.

Smiting Zeal

If the hero does not have enough mana to pay the additional cost, should the ability still activate? I think it shouldn't.
Similar to Seed of Life, the ValidateTarget function should take the casting unit as an argument instead of expecting users to use outside code like SpellEvent.CastingUnit in it.

Reverse Damage

FX_PLAY_DEATH_ANIM is not really needed, it can just cause odd compile errors if it is set to false and the user doesn't have TimedHandles in his map. You should use [ljass]LIBRARY_TimedHandles

in the static if statement instead and simply mention in the documentation of the FX_DURATION constant that it will be ignored if the TimedHandles library is not present.[*]The spell seems mostly useless right now, since it will in most cases reverse a single regular attack and players can't really get it to reverse stronger spells unless they make a lucky guess about when the opponent will cast them. Even then, the spell is limited in how much damage it can reverse. I can't open the map right now, but I'm guessing the spell is meant to be a weak innate ability rather than an ultimate. That's fine then I guess, but the code should support more useful spells as well, for example a simple value for minimum damage to trigger it in addition to the existing maximum damage reversed would allow users to make this into an effective damage spell blocker.[/list]

Reverse Damage, Prolonged Life and to a lesser extent Seed of Life are very similar spells. This is more of a hero design issue than a problem for a spell submission; after all, we accept single spells, so a spellpack with multiple similar spells is fine. Still, I wish the spells were a bit more diverse, if not in their default setups then at least in what their calibration sections allow you to do with them.

For example, with a bit more calibration options, Reverse Damage and Prolong Life could be the same spell. You'd just need a constant to tell if the spell should only trigger on lethal damage or not, another to determine the damage reduction percentage (so you can just block damage or fully reverse it or anything in between) in addition to the calibration values of the existing two spells. A single spell like that (you could still have two separate spells in the map to showcase the flexibility of the code) would be worth more than those two spells currently are.

Since these are meant to be buff spells, they should support dispel functionality. I realize the old periodic checks in combination with buff spells did this already, but that's a bad solution for multiple reasons: the periodic checks are wasteful and each such spell must be based on a different base spell (the number of which is limited) because buff spells based on the same spell don't stack. The latter is a problem even if you don't intend to support dispel, so instead, since you're already triggering large portions of the spell, it would be easy to use a self-targetting aura (auras, unlike buff spells, do stack even when based on the same ability) to display the buff. That still leaves the problem of detecting dispel, though, which could be solved by using a buff system like ABuff or IBS.

Another thing that comes to mind (and I am getting slightly off-topic here) is that there is use for a healing library. With a healing event, we could make more interesting spells for a healer-type hero. There's this, but it's terribly old and should be replaced by something newer.

Deaod · 01-28-2011, 05:01 PM

Version 1.2.0

This should fix almost every issue you brought up, Anitarf.
The only one it doesnt, is using a library dedicated to healing. And currently, i dont think i need to submit another library.

**Anitarf** · 01-28-2011, 09:59 PM

Quote:

Originally Posted by Deaod

This should fix almost every issue you brought up, Anitarf.
The only one it doesnt, is using a library dedicated to healing. And currently, i dont think i need to submit another library.

That's all right, like I said, it was an off-topic thought, not an approval requirement.

Approved.

**Vexorian** · 01-29-2011, 12:22 AM

There was a fourth spell contest?

Deaod · 02-08-2011, 04:17 PM

Version 1.2.1

Yes, i believe it was dropped though because only two people or so managed to submit an entry.

12-25-2009, 02:28 AM	#2
Kam User Join Date: Jan 2004 Posts: 476	Nice spells, I like the idea of a support damage hero. The seed of life was my favorite. __________________

Thread Tools	Search this Thread
Show Printable Version Email this Page	Search this Thread: Advanced Search