Table 3.1

[Here-b-Trollz]

Think of Table as an integer array. However, while a normal integer array can only use indexes 0 - 8191, Table can use any integer (even negatives). If you define the table as local, it acts just like a local integer array. If you define it as global, it acts like a global integer array.

Hmm... hopefully this will help:

JASS:

globals
   integer Counter = 1
endglobals

function Show takes nothing returns nothing
   local Table T=Table.create()
   set T[0]=1
   set T[1]=Counter+1

   call BJDebugMsg(I2S(T[0]))

   call TriggerSleepAction(5.)

   call BJDebugMsg(I2S(T[1]))

   call T.destroy()
endfunction

function Call takes nothing returns nothing
   call Show()
   call Show()
endfunction

Call will display 1 (5 second wait) 2 1 (5 second wait) 3

[the-thingy]

Ah, I see, thanks :)

So, under 'normal' circumstances, a local Table, and a single key should do fine?

Would there be any problem with using the same key in separate triggers, if t is local to each?

[Anitarf]

Originally Posted by the-thingy

Ah, I see, thanks :)

So, under 'normal' circumstances, a local Table, and a single key should do fine?

Would there be any problem with using the same key in separate triggers, if t is local to each?

It doesn't matter if it's a local or global variable. What matters is that whenever you call Table.create() that gives you a new associative array, so if you create two tables in two triggers (or in one, doesn't matter) and set them to two different variables (global or local, doesn't matter) data stored to one or the other won't conflict.

BTW, Trollz, that's not what your script would actually output.

[Vexorian]

All right I updated it, it is less pure but a little better, something like this requires to cover all gamecache usage else it is not a good idea to implement it along with other gamecaches, the difference is that you can use HandleTable and StringTable to have tables with different key types.

[cohadar]

I think you should not use macro parameter for mission key.
Better instead pass it to a constructor.
I misread it, thought $key$ was mission and it is I2S(this), nwm

EDIT:
Why you called this table when it is only a nice way of doing gamecache?
Why not simply call it Cache?

[waaaks]

is this the same as the Table trigger inside your xe system?

[Vexorian]

Table is just used by one of the xe samples, it is not part of xe.

[waaaks]

ok, so that means this table cant be a substitute for xe's table

[Vexorian]

Originally Posted by waaaks

ok, so that means this table cant be a substitute for xe's table

It actually means the opposite. There's no such a thing as xetable.

The Table library used by stormy dreams is an old version of this thing, you can safely upgrade.

[Rising_Dusk]

You know, only after having Anitarf explain to me what all of the vJass stuff in this does to me did it occur to me how awesome this really is. Mad props, Vex.

[Pyrogasm]

So, I needed a Table to store reals, and I realized that I would have to modify your library to do so. I ended up with this, and it seems to work:

JASS:

library Table initializer init
//***************************************************************
//* Table object
//* ------------
//*
//*   set t=Table.create() - instanceates a new table object
//*   call t.destroy()     - destroys it
//*   t[1234567]           - Get value for key 1234567
//*                          (zero if not assigned previously)
//*   set t[12341]=32      - Assigning it.
//*   call t.flush(12341)  - Flushes the stored value, so it
//*                          doesn't use any more memory
//*   t.exists(32)         - Was key 32 assigned? Notice
//*                          that flush() unassigns values.
//*   call t.reset()       - Flushes the whole contents of the
//*                          Table.
//*
//*   call t.destroy()     - Does reset() and also recycles the id.
//*
//*   If you use HandleTable instead of Table, it is the same
//* but it uses handles as keys, the same with StringTable.
//*
//***************************************************************

//=============================================================
    globals
        private constant integer MAX_INSTANCES=8100 //400000

    //=========================================================
        private gamecache gc
    endglobals

    private struct GTable[MAX_INSTANCES]
        method reset takes nothing returns nothing
            call FlushStoredMission(gc,I2S(this))
        endmethod

        private method onDestroy takes nothing returns nothing
            call FlushStoredMission(gc,I2S(this))
        endmethod
    endstruct

    //Hey: Don't instanciate other people's textmacros that you are not supposed to, thanks.
    //! textmacro Table__make takes name, type, key
    struct $name$ extends GTable

        method operator [] takes $type$ key returns integer
            return GetStoredInteger(gc,I2S(this),$key$)
        endmethod

        method operator []= takes $type$ key, integer value returns nothing
            call StoreInteger(gc,I2S(this),$key$, value)
        endmethod

        method flush takes $type$ key returns nothing
            call FlushStoredInteger(gc,I2S(this),$key$)
        endmethod

        method exists takes $type$ key returns boolean
            return HaveStoredInteger(gc,I2S(this),$key$)
        endmethod

    endstruct
    //! endtextmacro



    private function H2I takes handle h returns integer
        return h
        return 0
    endfunction
    
    //! runtextmacro Table__make("Table","integer","I2S(key)" )
    //! runtextmacro Table__make("StringTable","string","key" )
    //! runtextmacro Table__make("HandleTable","handle","I2S(H2I(key))" )

    //Pyrogasm Stuff:
    struct RealTable extends GTable

        method operator [] takes real key returns real
            return GetStoredReal(gc,I2S(this),R2S(key))
        endmethod

        method operator []= takes real key, real value returns nothing
            call StoreReal(gc,I2S(this),R2S(key), value)
        endmethod

        method flush takes real key returns nothing
            call FlushStoredReal(gc,I2S(this),R2S(key))
        endmethod

        method exists takes real key returns boolean
            return HaveStoredReal(gc,I2S(this),R2S(key))
        endmethod

    endstruct

    //=============================================================
    // initialize it all.
    //
    private function init takes nothing returns nothing
        call FlushGameCache(InitGameCache("libtable.gc"))
        set gc=InitGameCache("libtable.gc")
    endfunction
endlibrary

But anyway: I think that you should add a "RealTable" to this, as it is potentially useful to others, let alone myself.

[Vexorian]

I never thought of that mostly because storing anything other than integer is kind of lame?

What's that odd situation in which you ONLY need a real value and nothing integral?

[Ammorth]

I agree that storing anything other than an integer is lame (cause you should be using structs for handles) but I also needed a RealTable for one of my systems.

I wanted to use it for storing the widths of chars, and storing as an integer and dividing by some constant seemed like a waste of over-head.

[Pyrogasm]

I used it for storing Weights in my Pools library.

[Anitarf]

Originally Posted by Ammorth

I wanted to use it for storing the widths of chars, and storing as an integer and dividing by some constant seemed like a waste of over-head.

I had the exact same situation when converting the subtitle engine of my cinematic system into a stand-alone library, I saw no problem in just storing integers; the gamecache use alone makes division by a constant insignificant, especially if you don't do it for every character but only for the final sum of widths. There is really no need for a real table.