The Spell Request Thread (Now with vJASS!)

[darkwulfv]

Argh, did you really need to use ABC here? I was hoping that spell could be done with as few extra systems as possible, and I didn't see ABC being one of them. (Doesn't that use a unit's custom value? Maybe I'm confusing it with something else, but if it does, I can't use this particular version of the spell, since I already have a need for the custom value of units.)

Otherwise, it looks good. I don't know enough complicated JASS to know why the units are being sucked into an infinite void, though. Perhaps it's your Sparta call?

[Malf]

There was a choice, ABC or gamecache. Since I was already using vJass, why not go for moar speed, so I chose ABC since it was nice, clean and safe. It doesn't use custom value, since you are not allowed to attach structs to units. It attaches structs to triggers, timers and dialogs.

I am also thinking of just using an auxiliar knockback system, since I've just found out that it screws up at the timeframe between the explosion and the knockback callbacks.

But I'm going to fix it first, it's not impossible anyways. the knockback system will be my last resort.

SUPREME EDIT OF TEH DEATH

Table:

Black Hole

The Hero tears a rip in the fabric of space, creating a black hole that sucks nearby enemy units and consumes those who stray too near. After X seconds, the black hole collapses and explodes, dealing Y damage in a Z AOE radius. Units who got consumed by the black hole will also take damage and be thrown out of the void it was sucked into.

[Malf]

Huzzahdoublepostbumplol

I've fixed the problem, and it seems to be because of some wierd stuff with GroupAddGroup.. I think. I've replaced the loop with a forgroup call and it worked, now the only thing left to fix is the knockback, hurray =þ

SUPREME EDIT OF TEH DEATH

I EDITED THE WRONG POST AND ATTACHED THE MAP TO MY OTHER POST LOLOL!

Anyway, it's working fine now, after 8-10 runs through testing.

[Pyrogasm]

Yeah... uhhh... Some of those constants globals should be constant functions so that the level of the spell can be factored into them. These in particular:

• Radius
• Distance
• Expiration
• Speed
• Explosion Damage
• Explosion Radius
• Knockback Speed

And Darkwulfv, the options really are CSCache, ABC, or some form of attachment like grim001's thingey with global arrays.

[darkwulfv]

Lolsrsly?

I didn't know this spell would require those kinds of things. Weird. Oh well, thanks for the spell. When it's completely done (everything is perfect, basically), Have Pyro add it to the table.

[Pyrogasm]

Were you expecting me to use global arrays? :P

I would've used CSCache.

[Malf]

Voila!

Oh, and I've included the demomap for Ignitedstar's request, I forgot to add the ability to the hero the last time

[Ignitedstar]

I've tested it and... Excellent. It doesn't have aesthetics, but I can do that myself.

Oh boy, I really have to remember that expiration timers are a godsend (I will use them in the future).

I may have another request, but some other time. You guys are too busy at the moment. I can see that for sure.

[Malf]

I'm not too busy :D

But if you will request something like botanic's which is quite complicated, then I'd gladly refuse =þ

And I believe the dl count doesn't work @_@

[Tide-Arc Ephemera]

Yeah um... why does it say 0 downloads on Malf's black hole spell? Some people have downloaded it, I'm sure...

[Malf]

The black hole sucks the dl count as well. I've hard coded it to do so =þ

[Pyritie]

Okay here's my other request, posting it here anyway.

Fear - AoE (no damage) where enemy units run away from the caster in fear for X seconds.

Level 1 - 5 seconds
Level 2 - 10 seconds
...
Level 5 - 25 seconds

If you've played WoW it's like the warlock's fear spell.

You can use whatever icon, I don't mind. But if you want you can just use the banshee's possession spell.

[Dg!Mortal]

I saw you'r fireball spell it is the best of spells here. Can you tell me how you have detected collision in this spell?

[Tide-Arc Ephemera]

Why not just download it and open it in the World Editor...?

[Pyrogasm]

Here's the entire spell code, the collision is in the highlighted parts:

JASS:

//*****************************************************************************************\\
//                                  Spell Name: Fireball                                   \\
//                                Spell Author:  Pyrogasm                                  \\
//                                                                                         \\
//                               Follows the JESP Standard                                 \\
//*****************************************************************************************\\

//*****************************************************************************************\\
//                              Start Configuration Functions                              \\
//*****************************************************************************************\\
constant function Fireball_AbilityId takes nothing returns integer
    return 'A000' //Rawcode of the actual spell
endfunction

constant function Fireball_FireballDummyId takes integer Level returns integer
    return 'h002' //Rawcode of the unit that will be moved as the fireball
endfunction

constant function Fireball_DummyUnitId takes nothing returns integer
    return 'h000' //Rawcode of the dummy caster
endfunction

constant function Fireball_DummyStunSpellId takes integer Level returns integer
    return 'A001' //Rawcode of the dummy stun/damage spell
endfunction

constant function Fireball_DummyStunSpellOrderString takes integer Level returns string
    return "thunderbolt" //The orderstring for the dummy stun/damage spell
endfunction

constant function Fireball_FireballDuration takes integer Level returns real
    return 1.50 //The duration of the spell (how long the dummy unit lasts for)
endfunction

constant function Fireball_CollisionRadius takes integer Level returns real
    return 100.00 //How close to the fireball a unit has to be in order for the fireball to "collide"
endfunction

function Fireball_CollisionFilter takes unit FilterUnit, integer Level, player OwnerOfCaster returns boolean
    return GetWidgetLife(FilterUnit) > 0.405 and IsUnitEnemy(FilterUnit, OwnerOfCaster)
                  //Make your own filter for checking for units in range for a collision here
endfunction

constant function Fireball_TimerInterval takes integer Level returns real
    return 0.04 //How often the move timer runs (in seconds)
endfunction

constant function Fireball_DistancePerInterval takes integer Level returns real
    return 25.00 //How far the fireball moves each iteration
endfunction

constant function Fireball_CastSpawnOffset takes integer Level returns real
    return 100.00 //When the spell is cast, the fireball will be created this far away from the caster
                  //In the direction towards where the spell was cast
endfunction

constant function Fireball_CollideEffectPath takes integer Level returns string
    return "" //Optional special effect to be played on the position of the fireball when it collides
endfunction

//*****************************************************************************************\\
//                               End Configuration Functions                               \\
//*****************************************************************************************\\

function Fireball_CastConditions takes nothing returns boolean
    return GetSpellAbilityId() == Fireball_AbilityId()
endfunction

function Fireball_Filter takes nothing returns boolean
    return Fireball_CollisionFilter(GetFilterUnit(), bj_stockPickedItemLevel, bj_forceRandomCurrentPick)
endfunction

function Fireball_Callback takes nothing returns nothing
    local timer T = GetExpiredTimer()
    local integer ArrayIndex = GetCSData(T)
    local real X
    local real Y
    local real Offset
    local unit Dummy = GetArrayUnit(ArrayIndex, 3)
    local boolean OutOfBounds = false
    local group G
    local unit U3
    local unit CastDummy
    local integer DummyAbilityId
    local integer Level
    local real MoveCos
    local real MoveSin

    if GetWidgetLife(Dummy) > 0.405 then
        set Level = GetArrayInt(ArrayIndex, 5)
        set Offset = Fireball_DistancePerInterval(Level)

        set MoveCos = GetArrayReal(ArrayIndex, 1) //Due to some weird bug, you must set these to
        set MoveSin = GetArrayReal(ArrayIndex, 2) //Variables before using them.

        set X = GetUnitX(Dummy)+Offset*MoveCos
        set Y = GetUnitY(Dummy)+Offset*MoveSin

        if X < GetRectMinX(bj_mapInitialPlayableArea) then
            set OutOfBounds = true
        elseif X > GetRectMaxX(bj_mapInitialPlayableArea) then
            set OutOfBounds = true
        elseif Y < GetRectMinY(bj_mapInitialPlayableArea) then
            set OutOfBounds = true
        elseif Y > GetRectMaxY(bj_mapInitialPlayableArea) then
            set OutOfBounds = true
        endif

        if not(OutOfBounds) then
            call SetUnitX(Dummy, X)
            call SetUnitY(Dummy, Y)

            set G = GetArrayGroup(ArrayIndex, 4)
            set bj_stockPickedItemLevel = Level
            set bj_forceRandomCurrentPick = GetOwningPlayer(Dummy)
            call GroupEnumUnitsInRange(G, X, Y, Fireball_CollisionRadius(Level), Condition(function Fireball_Filter))

            set U3 = FirstOfGroup(G)
            if U3 != null then
                set DummyAbilityId = Fireball_DummyStunSpellId(Level)
                set CastDummy = CreateUnit(bj_forceRandomCurrentPick, Fireball_DummyUnitId(), X, Y, 0.00)
                call UnitAddAbility(CastDummy, DummyAbilityId)
                call SetUnitAbilityLevel(CastDummy, DummyAbilityId, Level)
                call IssueTargetOrder(CastDummy, Fireball_DummyStunSpellOrderString(Level), U3)
                call UnitApplyTimedLife(CastDummy, 'BTLF', 2.00)

                call DestroyEffect(AddSpecialEffect(Fireball_CollideEffectPath(Level), X, Y))
                call KillUnit(Dummy)
                set CastDummy = null
                set U3 = null
            endif

        else
            call KillUnit(Dummy)
        endif
    else
        call DestroyGroup(GetArrayGroup(ArrayIndex, 4))

        call DestroyArray(ArrayIndex)
        call PauseTimer(T)
        call DestroyTimer(T)
    endif

    set T = null
    set Dummy = null
endfunction

function Fireball_Cast takes nothing returns nothing
    local unit U = GetTriggerUnit()
    local location L = GetSpellTargetLoc()
    local real X = GetUnitX(U)
    local real Y = GetUnitY(U)
    local real X2 = GetLocationX(L)
    local real Y2 = GetLocationY(L)
    local real Angle = Atan2((Y2-Y),(X2-X))
    local real MoveCos = Cos(Angle)
    local real MoveSin = Sin(Angle)
    local integer Level = GetUnitAbilityLevel(U, Fireball_AbilityId())
    local integer ArrayIndex = NewArray(7, true)
    local real Offset = Fireball_CastSpawnOffset(Level)
    local timer T = CreateTimer()
    local unit Dummy = CreateUnit(GetOwningPlayer(U), Fireball_FireballDummyId(Level), X+Offset*MoveCos, Y+Offset*MoveSin, Angle*57.2958)

    call UnitApplyTimedLife(Dummy, 'BTLF', Fireball_FireballDuration(Level))

    call SetArrayReal(ArrayIndex, 1, MoveCos)
    call SetArrayReal(ArrayIndex, 2, MoveSin)
    call SetArrayObject(ArrayIndex, 3, Dummy)
    call SetArrayObject(ArrayIndex, 4, CreateGroup())
    call SetArrayInt(ArrayIndex, 5, Level)
    call SetCSData(T, ArrayIndex)

    call TimerStart(T, Fireball_TimerInterval(Level), true, function Fireball_Callback)

    call RemoveLocation(L)
    set L = null
    set Dummy = null
    set U = null
    set T = null
endfunction

//===========================================================================
function InitTrig_Fireball takes nothing returns nothing
    //Preloading
    local unit U = CreateUnit(Player(15), Fireball_FireballDummyId(1), 0.00, 0.00, 0.00)
    call UnitAddAbility(U, Fireball_DummyStunSpellId(1))
    call RemoveUnit(U)
    set U = null

    set gg_trg_Fireball = CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ(gg_trg_Fireball, EVENT_PLAYER_UNIT_SPELL_EFFECT)
    call TriggerAddCondition(gg_trg_Fireball, Condition(function Fireball_CastConditions))
    call TriggerAddAction(gg_trg_Fireball, function Fireball_Cast)
    
endfunction

Edit: I'll be updating the list of spells on the front page in a bit. I've got to install Leopard on my computer right now.